制作Arduino功率计测量电压电流及功耗

作为电子爱好者,我们常常依靠一些仪表或仪器来测量和分析电路。从简单的万用表到复杂的功率分析仪或DSOs,所有的仪表都有它们自己独特的用途。这些仪表的大部分都有成品,我们可以根据特定的需要来购买。有时我们可能会想自己制作一个仪表。例如,当我们准备做一个太阳能光伏项目时,我们想计算负载的功耗,在这种情况下,我们就可以用一个像Arduino这样的微控制器平台来构建我们自己的功率计了。
Arduino功率计测量电压电流

构建自己的功率计不仅可以降低成本,还可以为我们提供更深入了解开发测试功能的途径。例如,使用Arduino的功率计可以很容易地调整串口监视器上的监控结果,可以在串口上绘制图形,可以添加SD卡在预定义的时间内自动记录电压、电流和功率的数值。

功率计材料清单

  1. Arduino Nano
  2. LM358运放
  3. 7805
  4. LCD1602
  5. 0.22欧姆2瓦电阻
  6. 10k可调电阻
  7. 10k,20k,2.2k,1k电阻
  8. 0.1uF电容
  9. 测试负载
  10. 面包板

功率计电路图

下面是arduino功率计项目的完整电路图:
Arduino功率计电路图

为了便于理解,我们把arduino功率计电路被分为两个部分。电路的上半部分是测量单元,电路的下半部分是计算和显示单元。该电路测量范围适合于0-24V,考虑到太阳能光伏电池的规格,电流为0-1A。电路的基本原理是通过测量负载的电流和电压,从而计算出负载所消耗的能量,并将测量值显示在1602显示器上。

下面,我们再把电路分成多个功能块进行介绍,这样我们就能更清楚地了解电路是如何工作的。

测量单元

测量单元包含一个分压器可以帮助我们测量电压;一个非反向的运算放大器帮助我们测量通过电路的电流。上述电路的分压部分如下所示:
Arduino功率计电路图分压电路

这里输入电压是由Vcc表示的,就像前面说的,我们正在设计从0到24V的电压范围的电路。但是像Arduino这样的微控制器无法测量如此高的电压值,它只能测量0-5v的电压。因此,我们必须将0-24v的电压(转换)到0-5v。这因此我们通过使用一个分压电路来实现,如下所示。10k和2.2k电阻形成了分压电路,用下面的公式可计算出分压器的输出电压。

Vout = (Vin × R2) / (R1 + R2)

电路图中标记为Voltage的电压可以从两个电阻中间获得,这个转换后的电压就可以被输入到Arduino的模拟针中。接下来就是电流测量单元,我们知道微控制器只能读取模拟电压,所以我们需要将电流的值转换成电压。这时,可以通过在电路中添加一个电阻(并联)来实现,根据欧姆定律,它会降低电压值,这与流过它的电流成正比。这样获得的值会非常小,所以我们用一个运算放大器来放大它。电路如下所示:
电流测量电路

分流电阻(SR1)的值是0.22欧姆。就像之前说的,我们设计的是0-1A的测量电路,基于欧姆定律,我们可以计算出这个电阻的电压降,当最大的1A电流通过负载时,它的电压会在0.2V左右。这个电压对于微控制器来说是非常小的,我们使用一个运算放大器来将电压从0.2V放大到到更高。这个放大器的增益是21,所以0.2*21=4.2v。计算运算放大器增益的公式如下所示:

Gain = Vout / Vin = 1 + (Rf / Rin)

在例子中,Rf的值是20k而Rin的值是1k,这样我们就能获得21的增益值。然后,将放大器的放大电压输入到一个由电阻1k和电容0.1uf组成的的RC滤波电路,过滤掉耦合噪声。最后,将得到的电压输入到Arduino模拟针上。

测量单元最后的部分是电压调节电路。由于实际输入的电压可能是可变的,而Arduino和运算放大器需要一个稳定的+5V来保证正常工作,因此我们用7805稳压模块并添加一个噪声电容来进行电压调节。电路如下:
7805电压调节电路

计算和显示单元

在测量单元中,我们将电压和电流参数转换成了0-5v,使之可以用在Arduino模拟输入上。现在,我们需要将这些电压信号与Arduino连接起来,并将1602液晶显示器连接到Arduino上,这样我们就可以查看最终结果了。
Arduino功率计计算和显示单元

如上图所示,Voltage针与Arduino模拟针A3相连,而Current针连接到Arduino模拟针A4,1602液晶显示器的电源来自于7805输出的+5 V,同时将1602其它信号针与Arduino的数字数字针相连,以4-bit模式工作,同时我们使用了一个电位计(10 k)连接到1602的 Con 针用来调节LCD的对比度。

Arduino编程部分

硬件部分讨论结束后,现在轮到软件部分了。软件部分代码的基本思路是读取A3和A4上的模拟电压,并计算电压、电流和功率值,最后将其显示在LCD屏幕上。下面我们将代码分割成小段来解释。和所有Arduino程序一样,开始都是定义使用的引脚。在本例中,A3和A4针分别用于测量电压和电流,数字针3,4,8,9,10和11用于与Arduino进行交互。

int Read_Voltage  = A3;
int Read_Current  = A4;
const int rs = 3, en = 4, d4 = 8, d5 = 9, d6 = 10, d7 = 11; //1602 LCD 连接针
LiquidCrystal lcd(rs, en, d4, d5, d6, d7);

included一个名为“liquid crystal”的头文件。然后setup 函数中,初始化LCD显示屏,并将串口显示文本设置为“Arduino Wattmeter”,然后等待两秒钟。代码如下所示:

void setup() {
  lcd.begin(16, 2); //Initialise 16*2 LCD
  lcd.print(" Arduino Wattmeter"); 
  lcd.setCursor(0, 1);
  lcd.print("-Circuitdigest"); 
  delay(2000);
  lcd.clear();
}

在主循环函数中,我们使用analogread函数来读取A3和A4的电压值。我们知道Arduino ADC的输出值是0-1203,因为它有一个10位的ADC,这个值必须被转换成0-5v,可以通过乘以(5/1023)来完成。在硬件介绍部分,我们已经完成从0-24v到0-5v的电压转换,以及0-1a到0-5v的转换。所以现在我们要用一个乘数把这些值恢复到实际值。可以通过将其与乘数值相乘来完成。乘数的值可以用硬件部分提供的公式来计算,或者如果你已知电压和电流值,你可以实际计算它。本例遵循了后一种选择,因为它在现实中往往更准确。所以乘数的值是6.46和0.239。因此,代码如下所示:

float Voltage_Value = analogRead(Read_Voltage);
float Current_Value = analogRead(Read_Current);

Voltage_Value = Voltage_Value * (5.0/1023.0) * 6.46;
Current_Value = Current_Value * (5.0/1023.0) * 0.239;

如何提高测量精度?

上述计算实际电压和电流值的方法可以很好地工作。但是也有一个缺点,那就是测量的ADC电压和实际电压之间的关系不是线性的,因此得到的结果不会非常精确。为了提高精确度,我们可以用已知的一组值来建立测量的ADC值的集合,然后利用这些数据,使用线性回归方法推导出乘数方程。一旦我们计算出了实际电压和实际电流值,我们就可以用公式计算出功率(P=V*I)。然后使用下面的代码在LCD上显示这三个值。

 lcd.setCursor(0, 0);
 lcd.print("V="); lcd.print(Voltage_Value);
 lcd.print("  ");
 lcd.print("I=");lcd.print(Current_Value);

 float Power_Value = Voltage_Value * Current_Value;

 lcd.setCursor(0, 1);
 lcd.print("Power="); lcd.print(Power_Value);

完整测试代码

Arduino功率计测量电压电流图

/*
 * Wattmeter for Solar PV using Arduino
 * Dated: 2-10-2018
 * Website: www.basemu.com
 * Translation to:circuitdigest.com
 * Power LCD and circuitry from the +5V pin of Arduino whcih is powered via 7805
 * LCD RS -> pin 2
 * LCD EN -> pin 3
 * LCD D4 -> pin 8
 * LCD D5 -> pin 9
 * LCD D6 -> pin 10
 * LCD D7 -> pin 11
 * Potetnital divider to measure voltage -> A3
 * Op-Amp output to measure current -> A4
 */

#include <LiquidCrystal.h>   

int Read_Voltage  = A3;
int Read_Current  = A4;
const int rs = 3, en = 4, d4 = 8, d5 = 9, d6 = 10, d7 = 11; 
LiquidCrystal lcd(rs, en, d4, d5, d6, d7);

void setup() {
  lcd.begin(16, 2); 
  lcd.print(" Arduino Wattmeter"); 
  lcd.setCursor(0, 1);
  lcd.print("  With Arduino  "); 
  delay(2000);
  lcd.clear();
}
void loop() { 
 float Voltage_Value = analogRead(Read_Voltage);
 float Current_Value = analogRead(Read_Current);
 Voltage_Value = Voltage_Value * (5.0/1023.0) * 6.46;
 Current_Value = Current_Value * (5.0/1023.0) * 0.239;
 lcd.setCursor(0, 0);
 lcd.print("V="); lcd.print(Voltage_Value); 
 lcd.print("  "); 
 lcd.print("I=");lcd.print(Current_Value);
 float Power_Value = Voltage_Value * Current_Value;
 lcd.setCursor(0, 1);
 lcd.print("Power="); lcd.print(Power_Value); 
delay(200);
}
标签: