Arduino-字符串 -系列8

  • 内容
  • 评论
  • 相关

在Arduino中字符串一般用于存储文本,类似于在LCD或Arduino IDE串口监视器窗口中显示的文本信息。字符串也可用于存储用户的输入,例如,存储用户在连接Arduino的键盘上键入的某些字符。 Arduino程序中包含两种类型的字符串:

  1. 字符型数组,与C语言中使用的字符串相同。
  2. Arduino字符串,它允许我们在 sketch 中使用 String 对象。

在本章中,我们将学习字符串、对象以及Arduino sketch 中字符串的使用。在最后,将介绍在 sketch 中都包含哪种类型的字符串。

Arduino-字符串

字符串和字符数组

字符串是 char 类型的一系列字符。字符数组是存储在内存中的同一类型变量的连续序列。字符数组就是多个 char 变量字符组成的数组。字符数组末尾包含有一个额外特殊的 0 值元素的字符,就是所谓的“空结尾字符串”。

字符串和字符数组示例

字符串示例:创建字符串并将其打印到串口监视器窗口。

void setup() {
   char my_str[] = "Hello";
   Serial.begin(9600);
   Serial.println(my_str);
}
void loop() {
}

字符数组示例:下面的例子显示了字符数组是由什么组成的:

 void setup() {
   char my_str[6]; // 一个容纳5个字符串的数组
   Serial.begin(9600);
   my_str[0] = 'H'; // 字符数组由5个字符组成
   my_str[1] = 'e';
   my_str[2] = 'l';
   my_str[3] = 'l';
   my_str[4] = 'o';
   my_str[5] = 0;   //  第6个数组元素是一个空结尾字符
   Serial.println(my_str);
}
void loop() { 
}

通过学习,我们知道一个字符数组包含可打印字符串和空结尾字符 0 ,空结尾字符表明这是字符数组结束的地方。 在程序中,我们可以通过使用Serial.println()传递字符数组的名称,并将字符数组打印到Arduino IDE的串口监视器窗口中。

字符数组的修改

下面我们通过具体实例来学习,如下所示 :

void setup() {
   char like[] = "I like coffee and cake"; // 创建一个字符串
   Serial.begin(9600);
   // (1) 输出字符串
   Serial.println(like);
   // (2) 删除部分字符串
   like[13] = 0;
   Serial.println(like);
   // (3) 在字符串中替换一个单词
   like[13] = ' '; // 用空格替换空终止符
   like[18] = 't'; // 插入新单词
   like[19] = 'e';
   like[20] = 'a';
   like[21] = 0;  // 空结尾字符
   Serial.println(like);
}

void loop() {
}

串口监视器输出结果:

I like coffee and cake
I like coffee
I like coffee and tea

代码工作原理

创建和打印字符串

在上面给出的示例中,首先创建了一个新字符串"I like coffee and cake",然后在串行监视器窗口中显示 ,见示例中的 (1)。 此处输出“I like coffee and cake”。

截断字符串

接着,将字符串中的第14个字符替换为 0 ,见示例中的( 2 ) ,从而达到截断字符串的目的。在字符数组中是从 0 开始顺序计数的,因此第13个元素对应字符串第14个字符 。当打印字符串时,0 值空结尾字符之后的字符串将不会被打印出来。此时被截断的其他字符并不会消失,它们仍然存在于内存中,并且字符数组的大小仍然不变,惟一的区别是,任何处理字符串的函数都将只看到第一个空结尾字符之前的字符串。

在字符串中更改字符

最后,来看看示例中如何将单词“cake”替换为“tea”(3)。首先必须用“空格”替换数组[13]的空结尾字符,这样可以把字符串恢复到最初创建的格式。将单词“cake”的“cak”改写为单词“tea”,这是通过直接覆盖单个字符来实现的,“cake”的“e”被替换为一个新的空结尾字符 0。最终,新字符串实际上是以两个空结尾字符结束的,一个是字符串末尾的原始字符,另一个是替换“cake”中的“e”的新字符。在打印输出新字符串时实际上是没有任何区别的,因为打印输出字符串的函数在遇到第一个空结尾字符时就停止了。

修改字符数组的函数

前面的示例通过访问字符串中的单个字符达到手动相修改字符数组的目的。为了更简单的修改字符数组,您可以编写自己的函数,或者使用C语言库中的一些字符串函数。这些函数包括: String()charAt()compareTo()concat()c_str()endsWith()equals()equalsIgnoreCase()getBytes()indexOf()lastIndexOf()length()remove()replace()reserve()setCharAt()startsWith()toCharArray()substring()toInt()toFloat()toLowerCase()toUpperCase()trim()等。

看下面的示例:

void setup() {
   char str[] = "This is my string"; // 创建字符串
   char out_str[40]; // 字符串函数的输出
   int num; // 整型数
   Serial.begin(9600);

   // (1) 打印字符串
   Serial.println(str);

   // (2) 获取字符串长度(不包括空结尾字符)
   num = strlen(str);
   Serial.print("String length is: ");
   Serial.println(num);

   // (3) 获取数组的长度(包括空结尾字符)
   num = sizeof(str); // sizeof() is not a C string function
   Serial.print("Size of the array: ");
   Serial.println(num);

   // (4) 复制字符串
   strcpy(out_str, str);
   Serial.println(out_str);

   // (5) 在字符串的末尾添加一个字符串 (append)
   strcat(out_str, " sketch.");
   Serial.println(out_str);
   num = strlen(out_str);
   Serial.print("String length is: ");
   Serial.println(num);
   num = sizeof(out_str);
   Serial.print("Size of the array out_str[]: ");
   Serial.println(num);
}

void loop() {

}

输出结果:

This is my string
String length is: 17
Size of the array: 18
This is my string
This is my string sketch.
String length is: 25
Size of the array out_str[]: 40

工作原理

和上一个示例一样,首先创建了一个新字符串,然后在串行监视器窗口中显示出来。

获取字符串的长度, strlen() 函数的作用是:获取字符串的长度。字符串的长度只适用于可打印字符,不包括空结尾字符。该字符串包含17个字符,因此我们在串行监视器窗口中看到:“String length is: 17”。

获取数组的长度, 利用操作符 sizeof() 获取字符数组的长度(包含空结尾字符),因此字符数组的长度比字符串的长度多1,“Size of the array: 18”。sizeof() 看起来像一个函数,但是它是一个操作符,通常用来显示字符数组长度和字符串长度之间的差异。

复制一个字符数组,strcpy() 函数的作用是将 str[] 字符数组复制到 out_num[] 数组中。 strcpy() 函数将传递给它的第二个字符串(“str”)复制到第一个字符串(“out_str”)中。字符串的副本现在存在于 out_num[] 数组中,但是只占用数组的18个元素,所以数组中仍然有22个空闲的 char 元素,这可以在下一步骤使用,也就是在字符串的末尾添加字符串。

将字符串追加到字符串末尾,将一个字符串连接到另一个字符串,这是使用strcat() 函数来完成的,函数的作用是: 将传递给它的第二个字符串(“ sketch.”)放在传递给它的第一个字符串(“out_str”)的末尾。字符串连接之后,打印输出字符串的长度来显示新的字符串长度,然后再打印输出数组的长度,显示在一个40个元素的长数组中有一个25个字符的长字符串。 “String length is: 25”,“ Size of the array out_str[]: 40”。需要注意的是:25个字符的长字符串实际上占用了数组的26个字符,因为还要包含 0 这个空结尾字符 。